JENIS-JENIS TANDA KOMPUTER ERROR DAN CARA MENGATASINYA

• 
  

  8.1 Jenis-Jenis Error

  Dalam proses pembuatan program, bisa saja terjadi error yang menyebabkan program tidak berjalan sebagaimana mestinya. Dilihat dari penyebabnya ada 3 jenis error yang bisa terjadi, yaitu :

  
  

  1. Syntax error – adalah error yang disebabkan oleh kesalahan menulis kode program. Misalnya :

  salah menuliskan nama object, property atau methodnya. Error jenis ini relatif mudah ditangani,

  IDE VB 6 akan memberi tanda kode program mana yang menimbulkan syntax error.

  

  
  

  
  

  
  

  
  

  
  

  
  

  
  

  
  

  
  

  
  

  
  

  
  

  
  

  
  

  
  

  
  

  
  
  
  

  
  

  2. Runtime error – adalah error yang disebabkan oleh sistem komputer ketika melakukan sesuatu.

  Misalnya : menyimpan file ke disket tetapi disketnya tidak ada. Sistem akan “memberitahu”  kepada program informasi error yang terjadi. Informasi error yang penting diantaranya adalah nomer error dan deskripsi error. VB 6 “menyimpan” informasi error tersebut pada object Err. Melalui object Err inilah kita bisa menangani runtime error.

  
  

  
  

  
  

  
  

  

  
  

  
  

  
  

  
  

  
  

  
  

  
  
  
  
  

  
  

  
  

  
  

  
  

  
  

  3. Logical error – adalah error yang disebabkan oleh kesalahan logika pemrograman (dari si programer). Misalnya : salah meletakkan urutan kode program. Error jenis ini relatif sulit diketahui dan bisa saja baru diketahui setelah program di-compile menjadi executable file (*.exe). Kejadian seperti ini sering disebut sebagai bug.

  

  
  

  
  

  
  

  
  

  
  
  
  
  
  
  

  
  

  8.2 Menangani Runtime Error

  Untuk menangani runtime error, di dalam kode program dibuatkan bagian khusus untuk menangani error yang terjadi. Bagian khusus ini diberi tanda berupa <label>. Agar setiap error yang terjadi dapat ditangani oleh bagian khusus ini, pada awal kode program ditulis perintah berikut ini :

  On Error GoTo <label>

  Contoh :

  
  

  
  

  

  
  
  
  

  
  

  
  
  
  
  

  
  
  
  
  

  Selanjutnya untuk mengetahui informasi error apa yang terjadi, gunakan object Err. Object Err merupakan object built-in yang disediakan VB 6 untuk menangani error. Seperti halnya object yang  dibuat dengan kontrol/komponen (misalnya TextBox), maka object Err juga mempunyai property dan method.

  Property object Err yang penting diantaranya adalah property Number dan Description. Untuk mengetahui nomor error yang terjadi, gunakan property Number. Sedangkan untuk mengetahui deskripsi error yang terjadi, gunakan property Description. Dengan menggunakan property Number, kita bisa menangani setiap error dengan cara yang berbeda.

  Misalnya : untuk setiap error yang terjadi akan dimunculkan kotak pesan dengan bahasa Indonesia. Cara ini dapat Anda lihat pada contoh program. Setelah error ditangani, kode program dapat dikembalikan ke bagian tertentu dengan perintah Resume.

  Ada 3 bentuk perintah Resume, yaitu :

  ·         Resume – kembali ke kode program yang menimbulkan error. Biasanya digunakan untuk retry (mencoba lagi).

  ·         Resume <label> – kembali ke bagian tertentu pada kode program yang diberi tanda <label>.

  ·         Resume Next – kembali ke kode program berikutnya (kode program setelah kode program yang menimbulkan error). Biasanya digunakan untuk abort atau cancel (mengabaikan atau membatalkan).

  Contoh penggunaan perintah Resume dapat Anda lihat pada contoh program.

  
  

  Contoh Program : Error Handle

  1. Aktifkan VB 6 melalui tombol Start.
  2. Pada Jendela Form buatlah UI seperti ini :

  (Gunakan komponen Image dan CommandButton)

  

  
  

  
  
  
  
  
  

  3. Pengaturan property setiap object-nya adalah sebagai berikut :

  
  

   

  
  

  
  

  
  
  
  

  
  

  
  

  4. Buka Jendela Code dan pada bagian Code Editor, lalu ketikkan kode programnya sebagai berikut :

  Private Sub Command1_Click()

  Dim FileName As String

  Image1.Picture = Nothing

  FileName = InputBox("Ketikkan path dan nama file gambar :", "Open Picture File", FileName)

  If FileName <> "" Then

  Image1.Picture = LoadPicture(FileName)

  End If

  End Sub

  
  

  5. Simpan Form tersbut (nama file : frmLaterror.frm).

  
  

  Untuk mencoba program ini sebelumnya siapkan sebuah disket dan copy-kan 1 file gambar (misalnya file komputer.wmf ).

  Coba jalankan Project-nya :

  • Klik tombol Open Picture File, akan muncul kotak input.
  • Ketikkan lokasi (path) dan nama file gambar, misalnya : a:\komputer.wmf.
  • Masukkan disketnya, lalu klik tombol OK.
  • Gambar akan muncul   tidak terjadi error.
  • Keluarkan disketnya, lalu coba ulangi langkah sebelumnya.
  • Akan muncul kotak pesan error :

  
  

   

  
  

  
  

  
  

  
  

  
  

  
  

  
  

  
  

  
  

  Klik tombol Debug untuk melihat kode program mana yang menimbulkan runtime error.

  ·         Klik tombol End pada bagian Toolbar untuk menghentikan program.

  
  

  

  
  

  
  

  
  

  
  

  
  

  
  

  Agar program bisa menangani error, modifikasi kode programnya menjadi sebagai berikut :
  

  Private Sub Command1_Click()

  Dim FileName As String

  On Error GoTo AdaError

  Image1.Picture = Nothing

  FileName = InputBox("Ketikkan path dan nama file gambar :", "Open Picture File", FileName)

  If FileName <> "" Then

  Image1.Picture = LoadPicture(FileName)

  End If

  Exit Sub

  AdaError:

  MsgBox "Error No : " & Err.Number & vbCrLf & _

  Err.Description, vbCritical + vbOKOnly, Me.Caption

  End Sub

  
  

  Coba jalankan Project-nya

  Bila terjadi error seperti sebelumnya akan muncul kotak pesan error :
  
  
  

   

  
  

  
  

  
  

  
  
  

  
  

  Klik tombol OK.

  Program akan tetap berjalan. User bisa mengulangi perintah untuk membuka file gambar (disket dimasukkan lebih dulu agar tidak terjadi error lagi).

  Agar pesan error-nya menggunakan bahasa Indonesia, modifikasi kode programnya menjadi sebagai berikut :

  Private Sub Command1_Click()

  Dim FileName As String

  Dim ErrMsg As String

  On Error GoTo AdaError

  Image1.Picture = Nothing

  FileName = InputBox("Ketikkan path dan nama file gambar :", "Open Picture File", FileName)

  If FileName <> "" Then

  Image1.Picture = LoadPicture(FileName)

  End If

  Exit Sub

  AdaError:

  Select Case Err.Number

  Case 53

  ErrMsg = "File [" & FileName & "] tidak ada !"

  Case 71

  ErrMsg = "Disket belum dimasukkan !"

  Case Else

  ErrMsg = Err.Description

  End Select

  MsgBox ErrMsg, vbCritical + vbOKOnly, Me.Caption

  End Sub

  
  

  Coba jalankan Project-nya

  Bila terjadi error akan muncul kotak pesan error :

  
  

  
  

  
  

  Klik tombol OK.

  Program akan tetap berjalan.

  Lakukan try-and-error untuk melihat setiap nomer dan deskripsi error

  yang mungkin terjadi.

  
  

  Agar setelah error ditangani kode program dapat dikembalikan ke bagian tertentu, modifikasi lagi kode programnya menjadi sebagai berikut :

  
  
  

  Private Sub Command1_Click()

  Dim FileName As String

  Dim ErrMsg As String

  Dim Ask As VbMsgBoxResult

  On Error GoTo AdaError

  Awal:

  Image1.Picture = Nothing

  FileName = InputBox("Ketikkan path dan nama file gambar :", "Open Picture File", FileName)

  If FileName <> "" Then

  Image1.Picture = LoadPicture(FileName)

  End If

  Exit Sub

  AdaError:

  Select Case Err.Number

  Case 53

  ErrMsg = "File [" & FileName & "] tidak ada !"

  Case 71

  ErrMsg = "Disket belum dimasukkan !"

  Case Else

  ErrMsg = Err.Description

  End Select

  Ask = MsgBox(ErrMsg, vbCritical + vbRetryCancel, Me.Caption)

  Select Case Ask

  Case vbRetry

  If Err.Number = 53 Then Resume Awal Else Resume

  Case vbCancel

  Resume Next

  End Select

  End Sub

  
  

  Coba jalankan Project-nya

  Bila terjadi error akan muncul kotak pesan error :

  
  

  

  
  

  
  

  
  

  
  

  
  

  
  

  Klik tombol Retry untuk mencoba lagi (disketnya dimasukkan lebih dulu), atau klik tombol Cancel untuk membatalkan.